/* This program generates one HTML file. Specify  *
 * a valid file name for that file. The following *
 * line is the only line you need to change to    *
 * run this program.                              */
filename odsout 'c:\temp\drillexamplel.htm' ;

/* close the listing destination */
ods listing close;

/* create data set SALES */
data sales;
   length Region $ 4 State $ 2;
   format Sales dollar8.;
   input Region State Sales Year Qtr;
   datalines;
West CA 13636 1999 1
West OR 18988 1999 1
West CA 14523 1999 2
West OR 18988 1999 2
East MA 18038 1999 1
East NC 13611 1999 1
East MA 11084 1999 2
East NC 19660 1999 2
West CA 12536 1998 1
West OR 17888 1998 1
West CA 15623 1998 2
West OR 17963 1998 2
East NC 17638 1998 1
East MA 12811 1998 1
East NC 12184 1998 2
East MA 12760 1998 2
;

/* assign graphics options for ODS output */
goptions reset=all device=java
         xpixels=450 ypixels=400;

/* open the html destination for ODS output */
ods html file=odsout parameters=("DDLEVEL1"="{CHART}{pie}{G_INDEP}{State}{G_DEP}{Sales}|{G_INDEPV}");

/* Create a chart that uses HTML variable */
title1 'Company Sales, Mid Year';
proc gchart data=sales;
   vbar3d region / sumvar=sales
   group=year
   subgroup=state;
run;
quit;

/* close the html destination and
   open the listing destination */
ods html close;
ods listing;